Fastest possible multiplication routine?

ah, scrap the "H" is not modified. It's just me not remembering past-Santi decisions. I made MDL only print register modifications if they were modified to a DIFFERENT value than before (I guess that made sense to me when I coded it). Indeed, H, and D are modified (but just set to 0), haha. So, false alarm!

In this case MDL was interpreting "jr nc, $+4" fine. In this case it's fine, but I would avoid the use of "$". Some assemblers have different semantics for "$". For example, in standard z80 notation: "org 0; db $, $" should be the same as "db 0, 0", but in some assemblers, this will translate to "db 0, 1". So, if you want portable code to different assemblers, avoid the use of "$" as much as you can

Fantastic, this is even faster (CPC: 24µS) than NYYRIKKIS/Protons (CPC: 29.5µS) and the one I mentioned from CPCWiki (CPC: 29µS).

Another routine to multiply two 8 bit integers. It take between double and triple the time than fastest one but it uses no table and has no constraint.

;Effect: HL = D x E (integers)
;Modifies: AF, DE, HL.


DxCtoHL:
	ld	hl,0
	ld	a,d
	rra
	ld	d,h
	jr	nc,bit0
	ld	l,e
bit0:
	or	a
	rl	e
	rl	d
	rra
	jr	nc,bit1
	add	hl,de
bit1:
	or	a
	rl	e
	rl	d
	rra
	jr	nc,bit2
	add	hl,de
bit2:
	or	a
	rl	e
	rl	d
	rra
	jr	nc,bit3
	add	hl,de
bit3:
	or	a
	rl	e
	rl	d
	rra
	jr	nc,bit4
	add	hl,de
bit4:
	or	a
	rl	e
	rl	d
	rra
	jr	nc,bit5
	add	hl,de
bit5:
	or	a
	rl	e
	rl	d
	rra
	jr	nc,bit6
	add	hl,de
bit6:
	or	a
	rl	e
	rl	d
	rra
	ret	nc	; Back if bi7 = 0
	add	hl,de
	ret

I think it can be optimized.

This sequence:

or a
rl e

can be replaced by a single

sla e

There are probably other chances for optimization but that's an outstanding one.

@gdx That can be made faster by putting the 8-bit values in h and e.

http://map.grauw.nl/articles/mult_div_shifts.php#lrmultr

;
; Multiply 8-bit values
; In:  Multiply H with E
; Out: HL = result
;
Mult8:
    ld d,0
    ld l,d
    ld b,8
Mult8_Loop:
    add hl,hl
    jr nc,Mult8_NoAdd
    add hl,de
Mult8_NoAdd:
    djnz Mult8_Loop
    ret

It combines the sla e, rl d and rra in your code above into a single add hl,hl.

Just unroll the loop eight times.