PT3 + AYFX player

GREAT!!
going to test!

I've spotted a problem in the code of WYZ
It does not control the mixer in the SCC.
This is a issue, as when the PT3 player switch off
a channel, the SCC continues to play that note.

Here there is a patch to the patch able to override the problem,
modify the code here :
http://karoshi.msxgamesbox.com/index.php?topic=562.0
with this routine:

            LD HL,AYREGS            ;REPRODUCE SONIDO EN PSG
    
_LOUT:      OUT (C),A
            INC C
            OUTI
            DEC C
            INC A
            CP  13
            JR NZ,_LOUT
            OUT (C),A
            LD A,(HL)
            AND A
            JP  M,SCCOUT
            INC C
            OUT (C),A

;CLONA SONIDO AL SCC

;CANALES PSG    SCC
;     A 1+4
;     B 2+5
;     C 3


SCCOUT:     ;FRECUENCIA

            ld  a,0x3fh
            ld  (Bank3),a

            LD  HL,(AYREGS+0)       ;REPRODUCE SONIDO EN SCC
            LD  (SCC_REG+0),HL
            DEC HL                  ;CHORUS EN CANAL 4 OPCIONAL
            LD  (SCC_REG+6),HL      ;*
            LD  HL,(AYREGS+2)
            LD  (SCC_REG+2),HL
            DEC HL                  ;CHORUS EN CANAL 5 OPCIONAL
            DEC HL
            LD  (SCC_REG+8),HL      ;*
            LD  HL,(AYREGS+4)
            LD  (SCC_REG+4),HL

            ;VOLUMEN

            LD      A,(AYREGS+8)
            LD      (SCC_REG+0x0A),A
            LD      (SCC_REG+0x0D),A
            LD      A,(AYREGS+9)
            LD      (SCC_REG+0x0B),A
            LD      (SCC_REG+0x0E),A
            LD      A,(AYREGS+10)
            LD      (SCC_REG+0x0C),A
            

            ;MIXER
            ld a,(AYREGS+AR_Mixer)
            ld  b,a
            xor a
            bit 0,b
            jp nz,noA
            or  00001001B       ; A-> ch 1 & 4
noA:        bit 1,b
            jp  nz,noB
            or  00010010B       ; B-> ch 2 & 5
noB:        bit 2,b
            jp  nz,noC
            or  00000100B       ; C-> ch 3
noC:        ld (SCC_REG+0x0F),a
            
            RET

Any proposal in order to make this code more efficient and faster ?

maybe this?

ld a,(AYREGS+AR_Mixer)
xor 7
ld b,a
and 3
add a,a
add a,a
add a,a
or b
ld (SCC_REG+0x0F),a

edited; can't calculate binary

As usual when using rapidshare, the replayer sources posted in the first message of this thread, ayfxpt3_wip.rar have disappeared. I've been looking for the file in Shiru's page; but seems that actually they're not public anymore.

Anyone out there who can provide a link to this?

Great!, thanks Huey!